Thema "Re: Betonschachtkonus Kanalbau" in Programmierung

Betonschachtkonus Kanalbau

Hmooslechner — Sun, 24 Mar 2013 16:20:42 GMT

Ich will meinem freien 3D Polygonzug - gdl einen Kanalverlauf "aufprägen"

Mit welchen Programmiertools würdet Ihr so einen Schachtkonus herstellen?

Mit SOE-Befehlen will ichs nicht, weil die alles verlangsamen und bei Reihungen mit den Namen Probleme machen - allerdings - ..

(... allerdings wäre es, ein externes GDL mit einem SOE-Konus zu erstellen, das wiederholt aufgerufen wird - hat sowas schon wer versucht - gemacht?)

Den Schacht selber habe ich bisher so drin:


				cutpolya 2, 1, 0,    			!!!!!Schacht-Hauptzylinder
				0, 0, 979,
				Schachtradius-Schachtwanddicke, 360, 4015
				
					addz - Schachthoehen[k]
					cylind Schachthoehen[k], Schachtradius
					del 1
	
				cutend    						!!!!! Ende Schacht-Hauptzylinder

Irgenwas einfaches in der Art sollte es auch für den Konus oben drauf geben..

Es müßte wohl mit dem Cutform - Befehl zu machen sein - aber wie genau würde der Befehl dann aussehen?

Any better idea?

Re: Betonschachtkonus Kanalbau

Anonymous — Tue, 09 Apr 2013 05:23:16 GMT

Mit Morph?

Re: Betonschachtkonus Kanalbau

Hmooslechner — Wed, 10 Apr 2013 20:46:09 GMT

Morph im GDL?

Ich habs soweit schon lösen können - mit Hr. Beisters früherer Anregung, über ein textarray die Namen in jeder Wiederholung zu ändern.

Jetzt muß ichs noch schräg stellen, derzeit geht mein Schachtkonus noch zentral rauf, was für Kanalschächte nicht stimmt.

Re: Betonschachtkonus Kanalbau

Frank Beister — Wed, 10 Apr 2013 21:09:20 GMT

Das klingt irgendwie nach der Anwendung eines TUBE oder SWEEP-Befehls.
Oder nach einem REVOLVE. Das Verziehen des Rotationskörpers erreichst du (eigentlich) mit XFORM. Oder du nimmst gleich den SHELL-Befehl. Mit dem geht rotieren und verziehen in einem.

Re: Betonschachtkonus Kanalbau

Hmooslechner — Wed, 10 Apr 2013 21:28:37 GMT

Ich habe auch ans einfache Schräg stellen eines Kegels gedacht mit schrägen cutplanes, aber dann ist die Schnittkurve kein Kreis mehr, sondern Elliptisch. Es sol ja dann der Ausgleichsring draufgpassen.. und unten der eigentliche Schacht

Re: Betonschachtkonus Kanalbau

Hmooslechner — Wed, 10 Apr 2013 21:32:16 GMT

Andererseits - wer schaut in einen Kanalschacht rein? Wie genau muß sowas denn sein?

Zuviel 3D kostet nur Aufbauzeit...

Gehts nicht viel mehr um die Grundrissdarstellung und den Längenschnitt, der zum Bauen gebraucht wird?

Momentan brauch ichs 3D eigentlich nur zum Anpassen an eine Freifläche.. Dann gehts eh im Längenschnitt weiter und das 3D verschwindet in Wirklichkeit im Boden - unsichtbar. Was sichtbar bleibt wären verscheidene Kanaldeckel und Einlauf-Formen..

Re: Betonschachtkonus Kanalbau

Frank Beister — Wed, 10 Apr 2013 21:53:46 GMT

Die Frage der Genauigkeit stellt sich natürlich immer.
Schau mal hier: Skewer.
Sonst erzeuge das Teil mal als Shell und ziehe es ins 3D-Skript. Dann sollte ein EXTRUDEDSHELL herauskommen.

Re: Betonschachtkonus Kanalbau

Hmooslechner — Thu, 11 Apr 2013 09:23:20 GMT

Ah - Danke!

Re: Betonschachtkonus Kanalbau

Ma_Scht — Tue, 17 Mar 2020 11:13:26 GMT

Na, ich hätte NICHT gedacht, das ein außermittiger Betonkonus so ein komplexes Bauteil ist.
Mit 2 MASS ein paar EPS zur Korrektur und Verschneidung bekommt man es hin, aber da muss ich mal ein paar Nächste drüber schlafen.
Ne, hätte ich NICHT gedacht.

Re: Betonschachtkonus Kanalbau

Anonymous — Tue, 17 Mar 2020 15:12:38 GMT

Ist schon eine Weile her dass ich das programmiert habe. Kann deshalb nicht mehr im Detail sagen was ich mir dabei gedacht habe.
Soviel weiss ich noch: Ich habe 2 Kegel voneinander abgezogen und oben abgeschnitten.
Hier der Ausschnitt aus dem 3D Skript für den Konus.

!Bezugshöhe des Objekts = OK Schachtdeckel
!PARAMETER
!hd = Höhe Deckel
!hk = Höhe Konus
!s = Anzahl der Schachtringe ohen Boden
!hrr = Höhe Schachtring(e)
!hrb = Höhe Schachtring mit Boden
!dms = Durchmesser Schacht aussen
!dmd = Durchmesser Deckel
!e= Wandstärke Schacht
!mata = Material Schacht
!matb = Material Deckel

!INTERNE VORGABEN

IF i=1 THEN !hp = Höhe des Gesamtkegels des Konus vor dem Schneiden auf hk
LET hp = -dms*hk/(dmd-dms) !wird aus Vorgabeparametern berechnet
LET hz = (dms-2*e)*hk/((dms-2*e)-(dmd-2*e))
ENDIF

IF i=0 THEN
LET dmd=dms !Wenn kein Konus dann Deckeldurchmesser=Schachtdurchmesser
LET hk=0 !Wenn kein Konus dann Wert Parameter Konushöhe =0
ENDIF

200: ! KONUS
SET MATERIAL mata
ADDZ -hd
CUTPLANE ! Pyramiden OK Konus bzw. UK Deckel abschneiden
DEL 1

GROUP "Konus" ! Vollkorpus Konus
ADDZ -hk-hd
PYRAMID 2,hp,21,
dms/2,0,900+1,
dms/2,360,4000+1
DEL 1
ENDGROUP

GROUP "Hohlraum" !Abzugskorpus Konus
ADDX e
ADDZ -hk-hd
PYRAMID 2,hz,21,
dms/2-e,0,900+1,
dms/2-e,360,4000+1
DEL 2
ENDGROUP

result = SUBGROUP ("Konus","Hohlraum") !Abzug Vollkorpus abzügl Hohlraum

PLACEGROUP result ! Resultat des Abzugs generieren

KILLGROUP "Konus" !Gruppen wieder aufheben
KILLGROUP "Hohlraum"

CUTEND
RETURN

https://www.directupload.net/file/d/5761/hfm8u4nz_png.htm
Die Wandstärke des Konus ist im Modell immer waagrecht gemessen. Ich weis nicht wie das in der Realität ausgeführt wird.

Re: Betonschachtkonus Kanalbau

Ma_Scht — Mon, 23 Mar 2020 14:30:18 GMT

Hallo Egon,
Danke fürs raussuchen, ich habe es mir angesehen.
Gruß Mario
Beigefügt mein Vorschlag:

!!! 3D-SCHRPT
!!!!!!!!!! copyright Ma_Scht, Mrz. 2020 !!!!!!!!!!!!!!
!!!!!!!! For free use, but at one's own risk. !!!!!!!!
!!!!! Zur freien Verwendung, auf eigenes Risiko !!!!!!
!! Solidarität mit Alten & Kranken - haltet Abstand !!

!!!!!!!!!!! BASIS-WERTE ALLGEMEIN !!!!!!!!!!!!!
EPS = 0.00001
oberflaeche = 4 !!! "Beton, rauh"
winkel = 15
teilung = 360/winkel
radiAbstZ = 1.25 !!! vertikaler Abstand zw. den beiden Radien
wandungsStaerke = 0.150
statusCodeStandard = 13 !13
geglaettetJN = 1 !1

sc01 = 1 !1 !!! STATUS-CODE-Schalter des MASS-Befehls
sc04 = 1 !1
sc16 = 1 !1
sc32 = 0 !0
sc64 = 0 !0
sc128 = 0 !0

!!!!!!!!! BASIS-WERTE AUSSEN-KONUS !!!!!!!!!!!
hoeheZylinderUAKo = 0.25 !!! keiner gerader ZYLINDER oben, ÄUSSERER KONUS
hoeheZylinderOAKo = 0.35 !!! kleiner gerader ZYLINDER oben, ÄUSSERER KONUS
radiUAKo = 2.00 * 0.5 !!! Radius UNTEN, ÄUSSERER KONUS
radiOAKo = 0.965 * 0.5 !!! Radius OBEN, ÄUSSERER KONUS
radiOAversX = 0 !!! der Form halber ergänzt, aber der Konus wird später mittels ROTz gedreht wie er gebraucht wird.
radiOAversY = radiUAKo - radiOAKo - 10*EPS !!! das ergibt den max. zulässigen Versatz

!!!!!!!!! BASIS-WERTE INNEN-KONUS !!!!!!!!!!!
!hoeheZylinderUIKo = muss für jeden Pkt. errechnet werden !!! kleiner NICHT gerader ZYLINDER unten, INNERER KONUS
!hoeheZylinderOIKo = muss für jeden Pkt. errechnet werden !!! kleiner NICHT gerader ZYLINDER unten, INNERER KONUS
radiUIKo = (radiUAKo - wandungsStaerke) !!! Radius UNTEN, INNERER KONUS
radiOIKo = (radiOAKo - wandungsStaerke) !!! Radius OBEN, INNERER KONUS
radiOIversX = 0 !!! der Form halber ergänzt, aber der Konus wird später mittels ROTz gedreht wie er gebraucht wird.
radiOIversY = radiUAKo - radiOAKo - 10*EPS !!! das ergibt den max. zulässigen Versatz

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!! GRUPPE - AUSSEN_KONUS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
GROUP "AUSSEN_KONUS"
statusCode = statusCodeStandard
FOR i = 0 TO teilung ! unterste Ebene - das ist das 1. VIERTEL im MASS-Befehl
PUT radiUAko*SIN(i*winkel) * (1+EPS) ! X
PUT radiUAKo*COS(i*winkel) * (1+EPS) ! Y
PUT 0 ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! obere Ebene des ZYLUNDER-Stummel - das ist das 2. VIERTEL im MASS-Befehl
PUT radiUAKo*SIN(i*winkel) ! X
PUT radiUAKo*COS(i*winkel) ! Y
PUT hoeheZylinderUAKo ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! obere Ebene des KONUS - das ist das 3. VIERTEL im MASS-Befehl
PUT radiOAversX + radiOAKo*SIN(i*winkel) ! X
PUT radiOAversY + radiOAKo*COS(i*winkel) ! Y
PUT hoeheZylinderUAKo + radiAbstZ ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! obere Ebene des KONUS - das ist das 3. VIERTEL im MASS-Befehl
PUT radiOAversX + radiOAKo*SIN(i*winkel) * (1-10*EPS) ! X
PUT radiOAversY + radiOAKo*COS(i*winkel) * (1-10*EPS) ! Y
PUT hoeheZylinderUAKo + radiAbstZ + hoeheZylinderOAKo ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

MASS oberflaeche, oberflaeche, oberflaeche,
0.25*NSP/4, 0.75*NSP/4, sc01*1 + sc04*4 + sc16*16 + sc32*32 + ABS(geglaettetJN-1)*64 + sc128*128, 0.00,
GET(NSP)
ENDGROUP

!!!!! KEHRWOCHE im Stack !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FOR i = 1 TO NSP : hlp = GET(1) : NEXT i
!!!!! KEHRWOCHE im Stack !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!! GRUPPE - ABZUGSVOLUMINA_INNEN_KONUS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
GROUP "ABZUGSVOLUMINA_INNEN_KONUS"
!!!!!!!!!!!! INNEN-KONUS !!!!!!!!!!!!!!
laenge1 = 2*radiUAKo - 2*radiOAKo
alpha = ATN(radiAbstZ / (2*radiUAKo - 2*radiOAKo))
beta = 45 + 0.5*alpha
gamma = beta - alpha
h1 = wandungsStaerke * TAN(gamma)

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! unterste Ebene - das ist das 1. VIERTEL im MASS-Befehl
PUT radiUIko*SIN(i*winkel) * (1+EPS) ! X
PUT radiUIKo*COS(i*winkel) * (1+EPS) ! Y
PUT 0 ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! obere Ebene des ZYLUNDER-Stummel - das ist das 2. VIERTEL im MASS-Befehl
PUT radiUIKo*SIN(i*winkel) ! X
PUT radiUIKo*COS(i*winkel) ! Y
PUT hoeheZylinderUAKo + 0.5*h1*COS(i*winkel) - 0.5*h1 ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! obere Ebene des KONUS - das ist das 3. VIERTEL im MASS-Befehl
PUT radiOIversX + radiOIKo*SIN(i*winkel) ! X
PUT radiOIversY + radiOIKo*COS(i*winkel) ! Y
PUT hoeheZylinderUAKo + radiAbstZ + 0.5*h1*COS(i*winkel) - 0.5*h1 ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

statusCode = statusCodeStandard
FOR i = 0 TO teilung ! obere Ebene des KONUS - das ist das 3. VIERTEL im MASS-Befehl
PUT radiOIversX + radiOIKo*SIN(i*winkel) * (1-10*EPS) ! X
PUT radiOIversY + radiOIKo*COS(i*winkel) * (1-10*EPS) ! Y
PUT hoeheZylinderUAKo + radiAbstZ + hoeheZylinderOAKo ! Z
IF i = teilung THEN statusCode = -1
PUT statusCode
NEXT i

MASS oberflaeche, oberflaeche, oberflaeche,
0.25*NSP/4, 0.75*NSP/4, sc01*1 + sc04*4 + sc16*16 + sc32*32 + ABS(geglaettetJN-1)*64 + sc128*128, 0.00,
GET(NSP)
ENDGROUP

result1 = SUBGROUP ("AUSSEN_KONUS", "ABZUGSVOLUMINA_INNEN_KONUS")
PLACEGROUP result1

KILLGROUP "ABZUGSVOLUMINA_INNEN_KONUS"
KILLGROUP "AUSSEN_KONUS"

END:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

Re: Betonschachtkonus Kanalbau

Frank Beister — Sat, 29 May 2021 12:43:13 GMT

Ich wusste doch, dass wir das schon mal am Wickel hatten. Ich bin gerade auf der Suche nach so einem (möglichst flexiblen - keine Angst vor zu viel Parametern) Betonring-Revischacht. Die Außenanlagenvariante mit Stahldeckel. Was nehmt ihr da?

Re: Betonschachtkonus Kanalbau

graber — Mon, 06 Sep 2021 13:02:51 GMT

Ich finde es erstaunlich (und ärgerlich), dass sowas -ein (Beton)-Schacht- nicht in der Standard-MEP-Bibliothek enthalten ist!

Re: Betonschachtkonus Kanalbau

Ma_Scht — Tue, 07 Sep 2021 05:08:24 GMT

Naja Graber,
es ist schon recht speziell für den Tiefbau. Rollenbänder gibt es auch nicht und jeder wird was finden was fehlt. Das es KEINE Schiebefenster gibt, das ist ein Manko.
Gruß Mario

Re: Betonschachtkonus Kanalbau

graber — Tue, 07 Sep 2021 06:32:41 GMT

@Ma_Scht:
Zumindest in unserem Teil Österreichs ist der Kanal (Regenwasser und Schmutzwasser - speziell außerhalb des Gebäudes) u.a. als Teil der behördlichen Einreichung (Architekturplanung) bei jedem(!) Projekt mitabzugeben.
Und dieser besteht praktisch immer aus Rohren und Betonschächten.
Da kommen tatsächlich die Schiebefenster weit seltener zur Anwendung.