Thema "Re: Hilfe bei 3D GDL Objekt gesucht" in Programmierung

Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Mon, 03 Jun 2013 07:56:51 GMT

Hallo, ich möchte gerne ein 3 Objekt umbauen und verzweifele an den Höhen...

Ich brauche also einen fundierten GDL Objekt Beherrscher der mein Problem sicher in einigen Minuten gelöst hat.

Bitte per PM melden wer Lust und Zeit hat,

vielen Dank

Re: Hilfe bei 3D GDL Objekt gesucht

poeik — Tue, 04 Jun 2013 16:15:31 GMT

Wenn es ein Objekt aus der Standard-Bib. ist, schreib doch mal ins Forum was du erreichen willst.

Gruss, poeik

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Wed, 05 Jun 2013 06:02:02 GMT

Es ist ein Standardelement, und zwar das Geländer aus der Bibliothek "Geländer_Vert_gerade 16"
dort möchte ich den oberen Handlauf entfernen und die dazugehörigen vertikalen Stege, am Ende nur die untere Reihe Vertikale, dann eine Horizontale auf denen die Staketen stehen und eine Abschlusshorizontale.

Ähnlich dem hier
http://www.alpsteinzaeune.ch/index.php? ... rmetallbau

Das Dritte von links.

Re: Hilfe bei 3D GDL Objekt gesucht

poeik — Wed, 05 Jun 2013 10:23:47 GMT

Baue zuerst zwei neue Parameter nola und nolb für Breite und Stärke der Pfosten ein, sonst sind sie immer gleich wie die Stäbe:

Dann ändere das 3D-Script wie unten geschrieben. Die mit ! versehenen Zeilen haben nun keine Funktion mehr, in den roten Zeilen habe ich die Parameter für Pfostenbreite und Stärke eingebaut. Der Handlauf lässt sich nun aber nicht mehr einschalten, müsste man zusätzlich programmieren. Zudem bezieht sich die Geländerhöhe immer noch auf die Höhe inkl. Handlauf. Nicht perfekt aber so auf die Schnelle erfüllt es den Zweck vermutlich...

!! Railing Vert. Straight.gsm

IF gs_detlevel_3D="Off" then end

IF gs_shadow=0 THEN SHADOW OFF
IF gs_shadow=1 THEN SHADOW ON

pen gs_cont_pen

ADDx -a/2 !! Drag to Origo

!!!!!!!HANDRAIL!!!!!!!!

MATERIAL railing_mat

rotz -leca
rotx 90
cutplane
del 2

addx a
rotz 180+reca
rotx -90
cutplane
del 3

addz zzyzx-hrh_w/2-a_hohe-e_mod
addx -dx1

! tube 4, 4, 1+2+16+32,
! -hrw/2, -hrh/2, 0,
! hrw/2, -hrh/2, 0,
! hrw/2, hrh/2, 0,
! -hrw/2, hrh/2, 0,

! -1, 0, erhohung, 0,
! 0, 0, 0, 0,
! a+dx1+dx2, 0, erhohung*(a+dx1+dx2), 0,
! a+dx1+dx2+1, 0, erhohung*(a+dx1+dx2)-erhohung, 0

del 1

!!!!!!!UPPER CROSSBAR!!!!!!!!

addz -lh-ucbh_w/2-hrh_w/2
addx -dx1
tube 4, 4, 1+2+16+32,
-ucbw/2, -ucbh/2, 0,
ucbw/2, -ucbh/2, 0,
ucbw/2, ucbh/2, 0,
-ucbw/2, ucbh/2, 0,

-1, 0, erhohung, 0,
0, 0, 0, 0,
a+dx1+dx2, 0, erhohung*(a+dx1+dx2), 0,
a+dx1+dx2+1, 0, erhohung*(a+dx1+dx2)-erhohung, 0
del 3

!!!!!!!LOWER CROSSBAR!!!!!!!!

addz lh-a_hohe+lcbh_w/2-e_mod
addx -dx1
tube 4, 4, 1+2+16+32,
-lcbw/2, -lcbh/2, 0,
lcbw/2, -lcbh/2, 0,
lcbw/2, lcbh/2, 0,
-lcbw/2, lcbh/2, 0,

-1, 0, erhohung, 0,
0, 0, 0, 0,
a+dx1+dx2, 0, erhohung*(a+dx1+dx2), 0,
a+dx1+dx2+1, 0, erhohung*(a+dx1+dx2)-erhohung, 0
del 1

cutend
cutend

del 1

!!!!!!!!Vertical Bars!!!!!!!!

addx -dx/2
addz lh+lcbh_w

for n=1 to nob
addx n*dx
tube 4, 4, 1+2+16+32,
-bw/2, -bth/2, 0,
bw/2, -bth/2, 0,
bw/2, bth/2, 0,
-bw/2, bth/2, 0,

-erhohung2, 0, de+bar_w, 0,
0, 0, bar_w, 0,
0, 0, 0, 0,
erhohung2, 0, -de, 0
del 1
addz g_hohe/(nob-1)
next n

del nob

del 2

!!!!!!!!Legs!!!!!!!!

!*** Lower Legs ***

if nol<>1 then
dx2=(a-dx)/(nol-1)
endif

addx dx/2

for n=0 to nol-1
addx n*dx2
sprism_ railing_mat, railing_mat, railing_mat,
4, 0, 0, 0, 1, zzyzx-lh-2*ucbh_w, erho,
-nola/2, -nolb/2, 15,
nola/2, -nolb/2, 15,
nola/2, nolb/2, 15,
-nola/2, nolb/2, 15
del 1
if nol<>1 then addz g_hohe/(nol-1)
next n

del nol
if nol<>1 then del 1

!*** Upper Legs ***

addz zzyzx-hrh_w-lh
addx dx/2
for n=0 to nol-1
addx n*dx2
!tube 4, 4, 1+2+16+32,
! -bw/2, -bth/2, 0,
! bw/2, -bth/2, 0,
! bw/2, bth/2, 0,
! -bw/2, bth/2, 0,

! -erhohung2, 0, de+lh, 0,
! 0, 0, lh, 0,
! 0, 0, 0, 0,
! erhohung2, 0, -de, 0
del 1
if nol<>1 then addz g_hohe/(nol-1)
next n
del nol+1

DEL top

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Wed, 05 Jun 2013 12:04:24 GMT

Und das wars? Hast du das schon getestet?
Wäre zu cool... ich schaue es mir später an und teste es mal, vielen Dank

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Wed, 05 Jun 2013 12:20:39 GMT

http://img189.imageshack.us/img189/9004 ... 30605u.png

ich habe noch Anpassungswünsche die ich nicht hinbekomme.

- unten fehlen jetzt die Füsse
- Auf dem Bild sieht man, das die Fangpunkte noch auf der alten Höhe liegen, kann man das runterdrücken?

Vielen Dank

Re: Hilfe bei 3D GDL Objekt gesucht

poeik — Wed, 05 Jun 2013 13:01:12 GMT

Die Füsse fehlen nicht, aber du hast vermutlich bei Anzahl Pfosten Null eingegeben..?

Mit der Höhe der oberen Fangpunkte wird es schwierig. Da das Geländer auch geneigt verwendet werden kann (schräger Handlauf mit vertikalen Stäben) müsste man schon einiges ändern. Nicht nur im 3D-Script sondern auch im Master-Script. Wenn das Geländer geneigt wird stimmen die Fangpunkte übrigens schon im Original nicht.

Wie gesagt, das Ding ist nicht perfekt, aber das Original auch nicht

Gruss, poeik

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Wed, 05 Jun 2013 15:38:15 GMT

Ok, ich schaue nochmals, vielen Dank!!

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Mon, 10 Jun 2013 06:40:53 GMT

Noch eine Frage, ich habe nun das neue Geländer und es funktioniert sehr gut, aber wie kann ich das Vorschaubild ändern, das stimmt ja so nicht mehr.

Re: Hilfe bei 3D GDL Objekt gesucht

poeik — Mon, 10 Jun 2013 09:04:30 GMT

Im Objekt kannst du die 3D-Ansicht öffnen, photoreal darstellen lassen, mit einem Auswahlrahmen in die Zwischenablage kopieren und ins Fenster Vorschau einfügen.

Gruss, poeik

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Mon, 10 Jun 2013 09:37:41 GMT

meinst du in der Vorschau vom Finder? Ich habe es versucht, geht nicht, zumindest nicht so...

Re: Hilfe bei 3D GDL Objekt gesucht

poeik — Mon, 10 Jun 2013 11:48:35 GMT

Nein, das Fenster "Vorschau" und das Fenster "3D-Ansicht" im geöffneten GDL-Objekt.

Gruss, poeik

Re: Hilfe bei 3D GDL Objekt gesucht

bjoern1 — Mon, 10 Jun 2013 14:44:35 GMT

Ding Dong... natürlich...

Danke dir