Thema "Re: XML-Datei auslesen mittels GDL" in Programmierung

XML-Datei auslesen mittels GDL

Ma_Scht — Fri, 03 Dec 2021 11:35:44 GMT

Howdy zusammen,
kann ich mit dem GDL ADD ON "XML" beliebige XML-Dateien einlesen oder nur die die durch den XML-Konverter gerattert sind?
Gruß Mario

Re: XML-Datei auslesen mittels GDL

Anonymous — Fri, 03 Dec 2021 12:29:59 GMT

Nein beliebige, wenn sie xml-konform sind.
Hier wurde dazu einiges geschrieben, allerdings ist die Umsetzung nicht ganz einfach nachzuvollziehen.
http://gdl.graphisoft.com/tips-and-tric ... xml-add-on

Re: XML-Datei auslesen mittels GDL

Ma_Scht — Fri, 03 Dec 2021 12:43:37 GMT

Hi Jochen,
danke f. d. AW.

Ich möchte mir die Strichstärke der Stifte-Sets als Kreissiagramm darstellen lassen.
Das habe ich mit dem GDL ADDON "TEXT" auch hinbekommen, aber da kann ich nur TXTs laden und muss immer die XML vorher umbenennen. Das nervt.
Nun dachte ich mir, ich nehme das "XML" ADDON.
Tricky!

Deinen Link hatte ich auch schon gefunden, aber da ich im XML nicht so bewandert bin, habe ich da ziemliche Verständnisprobleme.

Aber ich gehe mal davon aus, dass AC eine XML exportiert, XML-konform ist, wie Du schreibst, oder?

Gruß Mario

Re: XML-Datei auslesen mittels GDL

runxel — Tue, 07 Dec 2021 10:28:02 GMT

Interessante Idee, Mario.
Sieh dir den Code unten mal an, damit kannst du direkt die XML lesen und hast die Stifte in einem Array.
In der XML stehen ja einige witzige Dinge drin. Z.B. ließe sich auch auslesen, wann das Stiftset das letzte mal geändert wurde.


! Stiftset hat 255 Einträge
dim		penwidth[255]

! Value inits
_ = ""
pos = ""
nodename = ""
nodevalue = ""
nodetype = ""
n_childnodes = 0
attrval = ""
attrname = ""


ch = open('xml', 'stifte.xml', 'rl')

! Initialen Positionsdeskriptor erhalten (= sind im Root)
r = input(ch, "NewPositionDesc", _, pos)
! pos @ AttributeFile

r = input(ch, "MoveToNode FromFirstChild Reg* ELEM", pos, nodename, nodevalue, nodetype)
! pos @ AttributeFile:RegisteredAttributes

r = input(ch, "NumberofChildNodes ELEM *", pos, n_childnodes)

! In den Node hineinbewegen
r = input(ch, "MoveToNode ToFirstChild", pos, nodename, nodevalue, nodetype)

! Durch Subnodes loopen, bis "Stifte" gefunden (Achtung, lokalisiert!)
for i=1 to (n_childnodes - 1)
	r = input(ch, "MoveToNode FromNextSibling A* ELEM", pos, nodename, nodevalue, nodetype)
	
	! Schauen, welchen Namen der Node hat (steht im Attribut "Type")
	r = input(ch, "GetAttribute Type", pos, attrval, attrname)
	
	if attrval = "Stifte" then
		goto "break"
	endif
next i
"break":

! Es wird immer die erste Stifttabelle ausgelesen
r = input(ch, "MoveToNode FromFirstChild PenTable ELEM", pos, nodename, nodevalue, nodetype)
! pos @ AttributeFile:RegisteredAttributes:Attributes[type=stifte]:PenTable

! Zum Übernode `Pens` hinein bewegen
r = input(ch, "MoveToNode FromFirstChild Pens ELEM", pos, nodename, nodevalue, nodetype)
! pos @ AttributeFile:RegisteredAttributes:Attributes[type=stifte]:PenTable:Pens

! In den Node hineinbewegen
r = input(ch, "MoveToNode ToFirstChild", pos, nodename, nodevalue, nodetype)
r = input(ch, "MoveToNode FromNextSibling Pen ELEM", pos, nodename, nodevalue, nodetype)
! pos @ 1. `Pen` Knoten

for i=1 to 255
	! Breite des Stifts auslesen und speichern im Array
	r = input(ch, "MoveToNode FromFirstChild Width ELEM", pos, nodename, nodevalue, nodetype)
	r = input(ch, "MoveToNode ToFirstChild", pos, nodename, nodevalue, nodetype)

	penwidth[i] = nodevalue

	! Ebene wieder nach oben
	r = input(ch, "MoveToNode ToParent", pos, nodename, nodevalue, nodetype)
	r = input(ch, "MoveToNode ToParent", pos, nodename, nodevalue, nodetype)
	! Zum nächsten Stift
	r = input(ch, "MoveToNode FromNextSibling Pen ELEM", pos, nodename, nodevalue, nodetype)
next i

Re: XML-Datei auslesen mittels GDL

Ma_Scht — Tue, 07 Dec 2021 12:00:35 GMT

Hi shadow,
Danke Dir, ja, das ist die Marschrichtung in der ich z.Z. auch unterwegs bin.
Hat etwas gedauert, bis ich die Handhabung, besonders die Abfangung des Fehlers, falls <Description> leer ist, der XML kapiert habe.

Nun suche ich nach einem Weg den DATEINAMEN der eingelesenen XML in einen Parameter zu schreiben.

Mein Ansatz ist, dass ich einen BOOL antippe (und gleich wieder ausschalte), Wenn der 1 ist, dann wird die Datei neu eingelesen. Um eine NEUE ID zu erzeugen, lese ich Datum und Uhrzeit vom System aus aus und setze sie als Dateinamen. Der wird logischerweise NICHT gefunden, damit springt die DIALOG-Option an und ich kann auswählen.
Prima, ABER:
Dieser ausgewählte Dateiname soll in einen Paramter, damit ich auch morgen noch weiß was ich auswählte.
Das kriege ich NICHT hin.

Wenn Du, oder wer anders, dazu einen Hinweis habt, wie ich eine über
kanal = OPEN ("XML", dateiNameOPEN, "rd")
eingelesene Dateiname auslesen kann.
Das würde mir sehr weiter helfen.
Ich brauche "dateiNameOPEN" NACH der Wahl.
Aus der XML bekomme ich ihn NICHT, woher soll sie es auch wissen.

Gruß Mario

Re: XML-Datei auslesen mittels GDL

runxel — Tue, 07 Dec 2021 16:58:22 GMT

Das geht wohl nicht.

Re: XML-Datei auslesen mittels GDL

Ma_Scht — Wed, 08 Dec 2021 07:50:41 GMT

Danke Dir!
Schade, aber unlogisch.
In dem Moment, wo ich die Datei über DIALOG anklicke, müssten die Daten doch da sein.

Re: XML-Datei auslesen mittels GDL

runxel — Wed, 08 Dec 2021 16:45:02 GMT

Gerne berichtigen, wenn ich da falsch liege. Habs probiert – ohne Erfolg.
Ich dachte erst, dass der Dateiname eventuell in der "filename" Variable gespeichert wird, aber das ist nicht der Fall. Stattdessen bleibt die Variable unverändert.

Und ja, die Daten liegen sicherlich vor. Aber nicht zugreifbar im GDL. Hat sich wohl keiner gedacht, dass das mal nötig sein könnte.

Re: XML-Datei auslesen mittels GDL

Frank Beister — Thu, 09 Dec 2021 08:45:57 GMT

Ich hatte das in früheren Versionen schon hinbekommen, kann aber sein, dass das durch Beschränkungen im Parameterskript seit AC19 nicht mehr geht.

Re: XML-Datei auslesen mittels GDL

Ma_Scht — Thu, 09 Dec 2021 17:58:48 GMT

Ich Iddi,
ich glaube ich habe es bald.
Der Schlüssel m.E. ist, dass man zuerst alle XML-Dateien in dem Verzeichnis ausliest.
Wärend man das macht, liest man einer Unterschleife über ein separates OPEN die GUID und das Stifte-Set aus
Stimmt beides, springt man aus der Schleife.

Re: XML-Datei auslesen mittels GDL

Ma_Scht — Mon, 13 Dec 2021 06:45:40 GMT

Howdy zusammen,
Ich komme NICHT an den Pfad, wenn ich die gewünschte Datei auslese, oder?
Ich muss immer 2 DIALOGE abarbeiten.
@BEISTER: War das bei Dir damals auch so, oder kamst du mit einem DIALOG an Pfad und Dateiname?

!!! 2D-SCRIPT !!!
HOTSPOT2 0,0
CIRCLE2 0,0,1.5

!!!! dateiOPEN2 um beliebiges Zeichen ergänzen um NEUE Kanalvergabe zu erwirken !!!
dateiOPEN2 = "c111"

!!!!! Verzeichnis auswählen !!!!!
y = 0
i = 1
DIM dateiNAMEN1[]
kanalB = OPEN ("FileMan", dateiOPEN2 , "FILES, DIALOG, FULLPATH")
n = 1 ! INPUT (kanalB, 0, 0, dateiNAMEN1)
WHILE n = 1 DO
dateiNAMEN1 = ""
n = INPUT (kanalB, 0, 0, dateiNAMEN1)
y = y - 1.00
TEXT2 0, y, dateiNAMEN1
i = i + 1
ENDWHILE
TEXT2 0,1,"kanalB: " + dateiOPEN2
CLOSE kanalB

!!!!! Datei auswählen !!!!!
y = 0
i = 1
DIM dateiName1[]
kanalA = OPEN ("XML", dateiOPEN2 , "rdf")
TEXT2 0,2,"kanalA: " + dateiOPEN2
CLOSE kanalA

Re: XML-Datei auslesen mittels GDL

Frank Beister — Mon, 13 Dec 2021 10:13:31 GMT

Kann sein, dass das damals auch nicht ging. Ich habe das ja anders gelöst, indem ich einen "Explorer nachgebaut" habe.
Du hast Post. 😉