topic Re: Railing - Diagonal Rails in GDL

Railing - Diagonal Rails

Lingwisyer — Mon, 26 Sep 2022 20:57:16 GMT

Hi all,

How would you go about creating diagonal rails within your handrail? I am wanting to create some cross braces and thought I could use a custom panel, but it doesn't stretch to fit...
The distance between posts varies at different points around the building, so is there a way to make them stretch to fit?

Ling.

Re: Railing - Diagonal Rails

Lingwisyer — Tue, 12 Jun 2018 08:45:36 GMT

No ideas? Looks like I might need to resort to scripting one... T_T

Re: Railing - Diagonal Rails

Laszlo Nagy — Sun, 17 Jun 2018 08:55:41 GMT

Yes, you would probably have to script it so that it will stretch properly. If you model it and save it as a Railing Panel, it will be static, it will probably not stretch (I think, I have not tried this).
I would try to create a custom Railing Panel, not a custom Post.

Re: Railing - Diagonal Rails

Barry Kelly — Mon, 18 Jun 2018 03:04:32 GMT

I just tried saving a custom railing panel.
Seems you will have to get the exact size for both horizontal and raking railings and also any different heights and widths of panels..
The custom panel does not stretch to suit the actual panel extents.

Or you need to figure out the script of a panel object and base your diagonals on the extents of the panel.
Just had a look at the "Built-in Panel' and typically the script is very difficult to follow.
It seems there is more to this basic object than just a flat panel with 4 bounding corner points.

Barry.

Re: Railing - Diagonal Rails

Barry Kelly — Mon, 18 Jun 2018 07:25:04 GMT

I have managed to figure out the node co-ordinates for the corners of the panel in the built-in panel macro.
These are PUT in the script just before the CPRISM{2} that creates the panel (actually there are 2 half thickness panels - not sure why exactly).
In the attached image you can see I have spheres at these points.
Then with a bit of maths I have calculated the railing angle and some x and y offsets that would be required for the nodes of a diagonal prism.
I have just added some lines at this point to get the width of the diagonal rail.

But it doesn't work when the railing is angled up a stair.
It seems I need to take into account the ROT of the panel in another way other than just calculating the angle of the railing.

So I am sure something is possible.
I will have more of a play later when I get some more free time.

Barry.

Re: Railing - Diagonal Rails

Barry Kelly — Wed, 20 Jun 2018 02:42:05 GMT

I have moved this entire post to Libraries/GDL section, as that is really what it has turned into.

It is possible to create a stretchy X panel.
Unfortunately I can not post the object here as I have simply modified the 'Built-in Panel' object by Graphisoft, and licensing requirements say I can not distribute a modified object.
Read here ...

https://archicad-talk.graphisoft.com/viewtopic.php?f=6&t=47320

However I can give instructions on how to modify the object for your own use.
So stay tuned.

Barry.

Re: Railing - Diagonal Rails

Barry Kelly — Wed, 20 Jun 2018 03:00:04 GMT

This is what you will need to do to create a X panel.

The 'Built-in Panel' object is not in the library as it is part of the Archicad program itself.
So to open it, create a railing using it, select it then CTRL+SHIFT+O.
Close all the other objects that open as they aren't needed.

'SAVE AS' with a new name - something like 'Cross panel'.

Create a new length parameter called ... rail_hgt

In the 3D script find and comment out this section (starting at line 263).

!!!!				group lowergroup
!!!!					for nSide = 1 to nTransformedPoly
!!!!						if segmentCutFlag[nSide] then
!!!!							_cutangle = segmentCutAngle[nSide]
!!!!						else
!!!!							_cutangle = 0
!!!!							if segmentContinueFlag[nSide] then
!!!!								if segmentSideFlag[nSide] = SIDE_END then _cutangle = _cutright
!!!!								if segmentSideFlag[nSide] = SIDE_START then _cutangle = _cutleft
!!!!							endif
!!!!						endif
!!!!						put transformedPoly[nSide][1], transformedPoly[nSide][2],
!!!!							_cutangle, transformedPoly[nSide][TRPOLY_STATUS], _matPanel
!!!!					next nSide
!!!!
!!!!					cprism_{2} _matPanel, _matPanel, _matPanel,
!!!!						nTransformedPoly, ac_panelThickness / 2,
!!!!						get(nsp - 2), -1, _matPanel
!!!!					gosub "flushBuffer"
!!!!				endgroup
!!!!
!!!!				group uppergroup
!!!!					for nSide = 1 to nTransformedPoly
!!!!						if segmentCutFlag[nSide] then
!!!!							_cutangle = segmentCutAngle[nSide]
!!!!						else
!!!!							_cutangle = 0
!!!!							if segmentContinueFlag[nSide] then
!!!!								if segmentSideFlag[nSide] = SIDE_END then _cutangle = _cutright
!!!!								if segmentSideFlag[nSide] = SIDE_START then _cutangle = _cutleft
!!!!							endif
!!!!						endif
!!!!						put transformedPoly[nSide][1], transformedPoly[nSide][2],	! [nSide][3] should be all the same
!!!!							-_cutangle, transformedPoly[nSide][TRPOLY_STATUS], _matPanel
!!!!					next nSide
!!!!
!!!!					addz ac_panelThickness
!!!!					mulz -1
!!!!					cprism_{2} _matPanel, _matPanel, _matPanel,
!!!!						nTransformedPoly, ac_panelThickness / 2,
!!!!						get(nsp - 2), -1, _matPanel
!!!!					gosub "flushBuffer"
!!!!					del 2
!!!!				endgroup

Directly after that add this ...

!!!The geometry for all the corner points
horiz_panel = (transformedPoly[2][1]-transformedPoly[1][1])*COS(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE])

vert_panel = (transformedPoly[3][2]-transformedPoly[2][2])/COS(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE])

end_rise = (transformedPoly[2][1]-transformedPoly[1][1])*SIN(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE])

cross_angle = ATN((vert_panel+end_rise)/horiz_panel)

panel_cross_angle_1 = cross_angle-panelSegmentData[iSegment][SEGMENT_SLOPEANGLE]

cross_x_rad_1 = (rail_hgt*0.5)/SIN(panel_cross_angle_1)

cross_y_rad_1 = (rail_hgt*0.5)/SIN(90-panel_cross_angle_1-panelSegmentData[iSegment][SEGMENT_SLOPEANGLE])

y_reduction_1 = cross_y_rad_1-(cross_y_rad_1*COS(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE]))

if panelSegmentData[iSegment][SEGMENT_SLOPEANGLE] <> 0 then
	x_reduction_1 = y_reduction_1/TAN(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE]*0.5)
else
	x_reduction_1 = 0
endif

panel_cross_angle_2 = ATN((vert_panel-end_rise)/horiz_panel)+panelSegmentData[iSegment][SEGMENT_SLOPEANGLE]

cross_x_rad_2 = (rail_hgt*0.5)/SIN(panel_cross_angle_2)

cross_y_rad_2 = (rail_hgt*0.5)/COS(panel_cross_angle_2-panelSegmentData[iSegment][SEGMENT_SLOPEANGLE])

y_reduction_2 = cross_y_rad_2-(cross_y_rad_2*COS(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE]))

if panelSegmentData[iSegment][SEGMENT_SLOPEANGLE] <> 0 then
	x_reduction_2 = y_reduction_2/TAN(panelSegmentData[iSegment][SEGMENT_SLOPEANGLE]*0.5)
else
	x_reduction_2 = 0
endif


				group lowergroup

						put transformedPoly[1][1], transformedPoly[1][2],
							0, 15, _matPanel
						put transformedPoly[1][1]+cross_x_rad_1, transformedPoly[1][2],
							0, 15, _matPanel
						put transformedPoly[3][1]-x_reduction_1, transformedPoly[3][2]-cross_y_rad_1+y_reduction_1,
							0, 15, _matPanel
						put transformedPoly[3][1], transformedPoly[3][2],
							0, 15, _matPanel
						put transformedPoly[3][1]-cross_x_rad_1, transformedPoly[3][2],
							0, 15, _matPanel
						put transformedPoly[1][1]+x_reduction_1, transformedPoly[1][2]+cross_y_rad_1-y_reduction_1,
							0, 15, _matPanel
						put transformedPoly[1][1], transformedPoly[1][2],
							0, 15, _matPanel


					cprism_{2} _matPanel, _matPanel, _matPanel,
						7, ac_panelThickness / 2,
						get(nsp - 2), -1, _matPanel

					gosub "flushBuffer"


						put transformedPoly[2][1], transformedPoly[2][2],
							0, 15, _matPanel
						put transformedPoly[2][1]+x_reduction_2, transformedPoly[2][2]+cross_y_rad_2-y_reduction_2,
							0, 15, _matPanel
						put transformedPoly[4][1]+cross_x_rad_2, transformedPoly[4][2],
							0, 15, _matPanel
						put transformedPoly[4][1], transformedPoly[4][2],
							0, 15, _matPanel
						put transformedPoly[4][1]-x_reduction_2, transformedPoly[4][2]-cross_y_rad_2+y_reduction_2,
							0, 15, _matPanel
						put transformedPoly[2][1]-cross_x_rad_2, transformedPoly[2][2],
							0, 15, _matPanel
						put transformedPoly[2][1], transformedPoly[2][2],
							0, 15, _matPanel

					cprism_{2} _matPanel, _matPanel, _matPanel,
						7, ac_panelThickness / 2,
						get(nsp - 2), -1, _matPanel

					gosub "flushBuffer"

				endgroup


				group uppergroup
					addz ac_panelThickness
					mulz -1

						put transformedPoly[1][1], transformedPoly[1][2],
							_cutangle, 15, _matPanel
						put transformedPoly[1][1]+cross_x_rad_1, transformedPoly[1][2],
							_cutangle, 15, _matPanel
						put transformedPoly[3][1]-x_reduction_1, transformedPoly[3][2]-cross_y_rad_1+y_reduction_1,
							_cutangle, 15, _matPanel
						put transformedPoly[3][1], transformedPoly[3][2],
							_cutangle, 15, _matPanel
						put transformedPoly[3][1]-cross_x_rad_1, transformedPoly[3][2],
							_cutangle, 15, _matPanel
						put transformedPoly[1][1]+x_reduction_1, transformedPoly[1][2]+cross_y_rad_1-y_reduction_1,
							_cutangle, 15, _matPanel
						put transformedPoly[1][1], transformedPoly[1][2],
							_cutangle, 15, _matPanel


					cprism_{2} _matPanel, _matPanel, _matPanel,
						7, ac_panelThickness / 2,
						get(nsp - 2), -1, _matPanel

					gosub "flushBuffer"


						put transformedPoly[2][1], transformedPoly[2][2],
							0, 15, _matPanel
						put transformedPoly[2][1]+x_reduction_2, transformedPoly[2][2]+cross_y_rad_2-y_reduction_2,
							0, 15, _matPanel
						put transformedPoly[4][1]+cross_x_rad_2, transformedPoly[4][2],
							0, 15, _matPanel
						put transformedPoly[4][1], transformedPoly[4][2],
							0, 15, _matPanel
						put transformedPoly[4][1]-x_reduction_2, transformedPoly[4][2]-cross_y_rad_2+y_reduction_2,
							0, 15, _matPanel
						put transformedPoly[2][1]-cross_x_rad_2, transformedPoly[2][2],
							0, 15, _matPanel
						put transformedPoly[2][1], transformedPoly[2][2],
							0, 15, _matPanel

					cprism_{2} _matPanel, _matPanel, _matPanel,
						7, ac_panelThickness / 2,
						get(nsp - 2), -1, _matPanel

					gosub "flushBuffer"
					del 2
				endgroup

In the interface script (edit: not parameter script) find these line starting at line 62 and comment them out.

!!!!	_yCurr = _pageStartY + 37
!!!!	ui_infield{3} ac_panelThickness, _x2, _yCurr, _infWidth, _infHeight

Then add ...


	_yCurr = _pageStartY + 37
	ui_infield{3} ac_panelThickness, _x2, _yCurr, _infWidth, _infHeight UI_TOOLTIP "Rail Width"

	ui_infield{3} rail_hgt, 380, 130, 50, _infHeight UI_TOOLTIP "Rail Height"

Now re-save and you should find it available as a panel type in your railing.
Of course you will need this in your loaded library or your embedded library.

I can't guarantee it will work in all situations (I haven't tried leaning the railing on an angle), but it seems to work for flat and rising (stair) railings.

Barry.

Re: Railing - Diagonal Rails

Lingwisyer — Fri, 22 Jun 2018 04:07:41 GMT

Wow, thanks Barry.

I had a separate post within the GDL sub-forum regarding programming a custom panel, so it should probably be merged or removed...

Ling.

Re: Railing - Diagonal Rails

Lingwisyer — Tue, 26 Jun 2018 08:26:58 GMT

In the parameter script find these line starting at line 62 and comment them out.
_yCurr = _pageStartY + 37
ui_infield{3} ac_panelThickness, _x2, _yCurr, _infWidth, _infHeight

Could not find this line in my Parameter Script, there was actually very little in it at all... Found it in the Interface Script which I'm assuming is what you meant given the _yCurr.

Re: Railing - Diagonal Rails

Barry Kelly — Tue, 26 Jun 2018 13:05:43 GMT

Yes, sorry I meant the interface script.

I think it should also be...

_yCurr = _pageStartY + 37
ui_infield{3} ac_panelThickness, _x2, _yCurr, _infWidth, _infHeight UI_TOOLTIP "Rail Width"
ui_infield{3} rail_hgt, 380, 130, 50, _infHeight UI_TOOLTIP "Rail Height"]

I think the formatting got messed up - seems it gets messed up when I tag it as code.
At least it is for me on this machine - not my regular machine.

It is just adding the rail height parameter and adding some tool tips.

I will fix the original post.

Barry.

Re: Railing - Diagonal Rails

Lingwisyer — Wed, 27 Jun 2018 01:22:39 GMT

Yeah... the code BB seems to be removing the page returns... Reasonably easy to spot where it breaks using Sublime.

Re: Railing - Diagonal Rails

kajnorberg — Tue, 11 Aug 2020 08:09:50 GMT

Hi!

After struggling with the custom panel and failing, I checked the forum and found this, which is exactly what I need! However, the coding of the built-in panel seems to have changed from the time this was made until now. I tried to edit it myself, but I just don't have the knowledge to do that. Does anyone know how to update the code so it works for Archicad 23?

Thank you!

Re: Railing - Diagonal Rails

Barry Kelly — Tue, 11 Aug 2020 09:17:12 GMT

kajnorberg wrote:
Does anyone know how to update the code so it works for Archicad 23?

Please don't wait for me on this one.
I would love to help but I just don't have the time at the moment to go back through it all again and see what is different in 23.
The bits I wrote before are still working in 23 for me and I don't remember changing anything.

If I can look at it next week maybe I will try, but as i say, what ever i did before is still working for me now in 23.

Barry.

Re: Railing - Diagonal Rails

kajnorberg — Tue, 11 Aug 2020 09:25:12 GMT

Hi Barry!

Thanks for your fast reply! I'll try to tinker with it myself, do you remember which version of Archicad you created the object in? Maybe I can open up an old version and make the changes there.

/Kaj

Re: Railing - Diagonal Rails

Lingwisyer — Tue, 11 Aug 2020 09:52:44 GMT

kajnorberg wrote:
Hi Barry!

Thanks for your fast reply! I'll try to tinker with it myself, do you remember which version of Archicad you created the object in? Maybe I can open up an old version and make the changes there.

/Kaj

I believe it was in AC22 as we were figuring out what other things you could do with railings at the same time.

Ling.

Re: Railing - Diagonal Rails

kajnorberg — Tue, 11 Aug 2020 10:15:43 GMT

Great, thanks!

/Kaj

Re: Railing - Diagonal Rails

Peter Baksa — Fri, 14 Aug 2020 07:56:45 GMT

Hi all,

Without trying to give a legal advice, the licensing of Graphisoft's library parts has changed to https://creativecommons.org/licenses/by/4.0/ from Archicad 23. I think that allows uploading modifications to this forum.

Re: Railing - Diagonal Rails

Peter Baksa — Fri, 14 Aug 2020 08:35:39 GMT

I can share an excerpt from a documentation in progress, hope this helps:

A panel is meant to be an object bounded by neighboring axial objects, described by a 3D polygon. Some care needs to be taken to connect nicely to neighboring panels when the pattern is cut by a post. Information is given about offsets to neighbors to allow modeling fixings.

Fix-named parameters
Read by ArchiCAD for listing and MVO – simplified display.

ac_panelThickness
The thickness of the panel section, assumed to be symmetrical to the surface defined by the 3D polygon.
This parameter should be kept conclusive with the model size.

Global variables

RAILING_REFLINE_DISTANCE[2]
[1] Horizontal offset of the Segment reference line from the Railing reference line.
[2] Horizontal offset of the Panel from the Segment reference line.
Distances are perpendicular to the reference line, + to the right side looking in the direction of the reference line, and without the effects of slanting.
RAILINGPANEL_TYPE
The overall geometry of the panel surface. Depends on segment rise, skew and slant settings. This data could be mined from RAILINGPANEL_GEOMETRY, this offers an easier way to decide whether you want to model these cases.
1: Plane
2: Cylindrical (vertical axis)
3: Conical (vertical axis)
4: Screw surface (not foldable to plane)
RAILINGPANEL_SKEW_ANGLE
The skew angle. For curved segments measured on the start tangential plane of the segment (before slanting). Range -90° + 90° exclusive, 0° is vertical.
RAILINGPANEL_SLANT_ANGLE
The slant angle. For curved segments measured on plane perpendicular to the start tangential plane of the segment (before skewing). Range -90° + 90° exclusive, 0° is vertical.
RAILINGPANEL_UNCUT_GEOMETRY[4] n >= 4
The 3D polygon of the boundary of the whole panel. Given as if the panel would end normally at a full pattern length, and not cut by posts and connections to other segments. This might be important for the layout of fixings, and the continuation of the panel’s inner pattern when the Continue Pattern option is set at a Node. The last point of the boundary is the same as the first, it is a closed polygon.
[][1] Coordinate X
[][2] Coordinate Y
[][3] Coordinate Z
[][4] For curved segments the polar coordinate rotation difference of the horizontal projection of the edge starting from this vertex. Degrees, + direction counterclockwise. 0 for straight segments.
The origin and orientation of the coordinate system doesn’t have any meaning other than Z is always vertical. The order of the points in the polygon is the same as in RAILINGPANEL_SIDE_OFFSETS: bottom, end, top, start sides.
It can have more than 4 corners when placed on a winding stair. In such cases the lower boundary’s horizontal projection is always a straight line or a continuous arc. The edges belonging to the lower boundary define sub-segments of the panel. Different sub-segments can have diferent rise angle.
RAILINGPANEL_GEOMETRY[5] n >= 4
The 3D polygon of the boundary of the cut panel. Cuts can happen at railing segment boundaries (posts) and at connections to other segments that have different height or rise.
[][1] Coordinate X
[][2] Coordinate Y
[][3] Coordinate Z
[][4] For curved segments the polar coordinate rotation difference of the horizontal projection of the edge starting from this vertex. Degrees, + direction counterclockwise. 0 for straight segments.
[][5] For cut edges the angle between the cutting plane and the plane perpendicular to the panel (for curved panels perpendicular to the tangential plane of the panel) at the edge. 0° means a perpendicular cut, + values tilt towards the inside of the panel (side at which a Right Side handrail is placed).
When there are no cuts, the data is the same as in RAILINGPANEL_UNCUT_GEOMETRY.
RAILINGPANEL_FLAGS[3] n >= 4
Information about the edges of the cut boundary. Indexed the same way as RAILINGPANEL_GEOMETRY.
[][1] The sub-segment index of the edge starting from this point. Uncut panel sub-segment indexes start from 1, it is possible that one or more sub-segments are cut off.
[][2] Which side of the panel is the edge starting from this point?
1: bottom
2: end
3: top
4: start
[][3] Edge status bitfield: j1 + 2 * j2
j1: Does the edge starting from this point connect to another panel? Edges having this flag should be modeled as if the panel continued through them.
j2: Is the edge starting from this point a cut edge? Cut edges should use RAILINGPANEL_GEOMETRY[][5] to connect to other panels without overlap at corners.
RAILINGPANEL_SIDE_OFFSETS[4]
The side offsets of the panel, distance to the neighboring sub-element’s axis.
[1] bottom
[2] end
[3] top
[4] start
The distances are as set in the settings dialog for a vertical panel, without the effect of slanting and skewing.

Re: Railing - Diagonal Rails

kajnorberg — Fri, 02 Oct 2020 12:36:11 GMT

Barry wrote:

Please don't wait for me on this one.
I would love to help but I just don't have the time at the moment to go back through it all again and see what is different in 23.
The bits I wrote before are still working in 23 for me and I don't remember changing anything.

If I can look at it next week maybe I will try, but as i say, what ever i did before is still working for me now in 23.

Barry.

Hey, since Péter mentioned it's now okay to upload modifications to the forum, can I ask you to upload your railing panel? I've been trying to fix it myself, but have yet to succeed. Thank you!

/Kaj

Re: Railing - Diagonal Rails

Lingwisyer — Mon, 05 Oct 2020 01:31:32 GMT

Is the licencing change retroactive?