BIM Coordinator Program (INT) April 22, 2024

Find the next step in your career as a Graphisoft Certified BIM Coordinator!

Libraries & objects
About Archicad and BIMcloud libraries, their management and migration, objects and other library parts, etc.

Platonic bodies

Anonymous
Not applicable
In this post I expose the text 3D to build Platonic bodies, that are in 3D the equivalent shapes of regular polygons in 2D.


1) Tetrahedron
!!Script 3D
L=1 !side
VERT l*sqr(3)/3, 0.0, 0.0 !#1A
VERT -l*sqr(3)/6,-l/2, 0.0 !#2B
VERT -l*sqr(3)/6,l/2, 0.0 !#3C
VERT 0.0, 0.0, l*sqr(2/3) !#4D alt.=l*sqr(2/3)
EDGE 1, 2, -1,-1,0 !#1AB
EDGE 2, 3, -1,-1,0 !#2BC
EDGE 3, 1, -1,-1,0 !#3CA
EDGE 1, 4, -1,-1,0 !#4AD
EDGE 2, 4, -1,-1,0 !#5BD
EDGE 3, 4, -1,-1,0!#6CD
PGON 3, 0, -1, 1,2,3 !#1ABC
PGON 3, 0, -1, -3,6,-4 !#2ACD
PGON 3, 0, -1, -5,-1,4 !#3DBA
PGON 3, 0, -1, -6,-2,5 !#4DCB
end
2) Octahedron
!!Script 3D
L=1 !side
r=l*cos(45)
material m
VERT 0.0, 0.0, 0.0 !#1A
VERT l, 0.0, 0.0 !#2B
VERT l, l, 0.0 !#3C
VERT 0.0, l, 0.0 !#4D
VERT l/2, l/2, l*cos(45) !#5E
VERT l/2, l/2,-l*cos(45) !#6F
EDGE 1, 2, -1, -1, 0 !#1AB
EDGE 2, 3, -1, -1, 0 !#2BC
EDGE 3, 4, -1, -1, 0 !#3CD
EDGE 4, 1, -1, -1, 0 !#4DA
EDGE 1, 5, -1, -1, 0 !#5AE
EDGE 2, 5, -1, -1, 0 !#6BE
EDGE 3, 5, -1, -1, 0 !#7CE
EDGE 4, 5, -1, -1, 0 !#8DE
EDGE 1, 6, -1, -1, 0 !#9AF
EDGE 2, 6, -1, -1, 0 !#10BF
EDGE 3, 6, -1, -1, 0 !#11CF
EDGE 4, 6, -1, -1, 0 !#12DF
PGON 3, 0, -1, 6, -5, 1 !#1BEA
PGON 3, 0, -1, -11,-2,10 !#2FCB
PGON 3, 0, -1, -4,12,-9 !#3ADF
PGON 3, 0, -1,-6, 2, 7 !#4EBC
PGON 3, 0, -1,11,-12, -3 !#5CFD
PGON 3, 0, -1, 4,5, -8 !#6DAE
PGON 3, 0, -1,8, -7, 3 !#7DEC
PGON 3, 0, -1, 9,-10, -1 !#8AFB
end

3) Dodecahedron
!!Script 3D
L=1 !side
r=0.5*l/sin(36)
s=2*r*cos(36)
d=s*cos(36)-r*cos(36)
i=l*cos( 18 )
h=(i*i-d*d)^0.5
k=h*(s-r*cos(36))/d
VERT r, 0.0, 0.0 !#1A
VERT r*cos(72), r*sin(72), 0 !#2B
VERT r*cos(2*72), r*sin(2*72), 0 !#3C
VERT r*cos(3*72), r*sin(3*72), 0 !#4D
VERT r*cos(4*72), r*sin(4*72), 0 !#5E
VERT s, 0.0, h !#6F
VERT s*cos(72), s*sin(72), h !#7G
VERT s*cos(2*72), s*sin(2*72), h !#8H
VERT s*cos(3*72), s*sin(3*72), h !#9I
VERT s*cos(4*72), s*sin(4*72), h !#10L
VERT s*cos(36), s*sin(36), k !#11M
VERT s*cos(3*36), s*sin(3*36), k !#12N
VERT s*cos(5*36), s*sin(5*36), k !#13O
VERT s*cos(7*36), s*sin(7*36), k !#14P
VERT s*cos(9*36), s*sin(9*36), k !#15Q
VERT r*cos(36), r*sin(36), h+k !#16R
VERT r*cos(3*36), r*sin(3*36),h+k !#17S
VERT r*cos(5*36), r*sin(5*36),h+k !#18T
VERT r*cos(7*36), r*sin(7*36),h+k !#19U
VERT r*cos(9*36), r*sin(9*36),h+k !#20V
EDGE 1,2, -1, -1, 0 !#1 AB
EDGE 2,3, -1, -1, 0 !#2 BC
EDGE 3,4, -1, -1, 0 !#3 CD
EDGE 4,5, -1, -1, 0 !#4 DE
EDGE 5,1, -1, -1, 0 !#5 EA
EDGE 1,6, -1, -1, 0 !#6 AF
EDGE 2,7, -1, -1, 0 !#7 BG
EDGE 3,8, -1, -1, 0 !#8 CH
EDGE 4,9, -1, -1, 0 !#9 DI
EDGE 5,10, -1, -1, 0 !#10 EL
EDGE 6,11, -1, -1, 0 !#11 FM
EDGE 11,7, -1, -1, 0 !#12 MG
EDGE 7,12, -1, -1, 0 !#13 GN
EDGE 12,8, -1, -1, 0 !#14 NH
EDGE 8,13, -1, -1, 0 !#15 HO
EDGE 13,9, -1, -1, 0 !#16 OI
EDGE 9,14, -1, -1, 0 !#17 IP
EDGE 14,10, -1, -1, 0 !#18 PL
EDGE 10,15, -1, -1, 0 !#19 LQ
EDGE 15,6, -1, -1, 0 !#20 QF
EDGE 11,16, -1, -1, 0 !#21 MR
EDGE 12,17, -1, -1, 0 !#22 NS
EDGE 13,18, -1, -1, 0 !#23 OT
EDGE 14,19, -1, -1, 0 !#24 PU
EDGE 15,20, -1, -1, 0 !#25 QV
EDGE 16,17, -1, -1, 0 !#26 RS
EDGE 17,18, -1, -1, 0 !#27 ST
EDGE 18,19, -1, -1, 0 !#28 TU
EDGE 19,20, -1, -1, 0 !#29 UV
EDGE 20,16, -1, -1, 0 !#30 VR
PGON 5, 0, -1,-1,-5,-4,-3,-2 !#1BAEDC
PGON 5, 0, -1,-16,-15,-8,3,9 !#2 IOHCD
PGON 5, 0, -1,8,-14,-13,-7,2 !#3 CHNGB
PGON 5, 0, -1,1,7,-12,-11,-6 !#4 ABGMF
PGON 5, 0, -1,-10,5,6,-20,-19 !#5 LEAFQ
PGON 5, 0, -1,-17,-9,4,10,-18 !#6 PIDEL
PGON 5, 0, -1,29,30,26,27,28 !#7 UVRST
PGON 5, 0, -1,14,15,23,-27,-22 !#8 NHOTS
PGON 5, 0, -1,-23,16,17,24,-28 !#9 TOIPU
PGON 5, 0, -1,-29,-24,18,19,25 !#10 VUPLQ
PGON 5, 0, -1,21,-30,-25,20,11 !#11 MRVQF
PGON 5, 0, -1,13,22,-26,-21,12 !#12 GNSRM
end

4) Icosahedron
!!Script 3D
l=1
r=0.5*l/sin(36)
h=r*( (2*cos(36)-2*cos(72))^0.5)
k=r*( (2*sin(36)*sin(36)-cos(72) )^0.5 )
p=0.5*h+k
VERT r, 0, k !#1A
VERT r*cos(72), -r*sin(72), k !#2B
VERT r*cos(2*72), -r*sin(2*72), k !#3C
VERT r*cos(3*72), -r*sin(3*72), k !#4D
VERT r*cos(4*72), -r*sin(4*72), k !#5E
VERT r*cos(36), -r*sin(36), h+k !#6F
VERT r*cos(3*36), -r*sin(3*36), h+k !#7G
VERT r*cos(5*36), -r*sin(5*36), h+k !#8H
VERT r*cos(7*36),- r*sin(7*36), h+k !#9I
VERT r*cos(9*36), -r*sin(9*36), h+k !#10L
VERT 0,0, h+2*k !#11M
VERT 0,0,0 !#12N
EDGE 1, 10, -1, -1, 0 !#1AL
EDGE 10, 5, -1, -1, 0 !#2LE
EDGE 5, 9, -1, -1, 0 !#3EI
EDGE 9, 4, -1, -1, 0 !#4ID
EDGE 4, 8, -1, -1, 0 !#5DH
EDGE 8, 3, -1, -1, 0 !#6HC
EDGE 3, 7, -1, -1, 0 !#7CG
EDGE 7, 2, -1, -1, 0 !#8GB
EDGE 2, 6, -1, -1, 0 !#9BF
EDGE 6, 1, -1, -1, 0 !#10FA
EDGE 6,10, -1, -1, 0 !#11FL
EDGE 10,9, -1, -1, 0 !#12LI
EDGE 9,8 , -1, -1, 0 !#13IH
EDGE 8,7 , -1, -1, 0 !#14HG
EDGE 7,6 , -1, -1, 0 !#15GF
EDGE 1,5, -1, -1, 0 !#16AE
EDGE 5,4, -1, -1, 0 !#17ED
EDGE 4,3, -1, -1, 0 !#18DC
EDGE 3,2, -1, -1, 0 !#19CB
EDGE 2,1, -1, -1, 0 !#20BA
EDGE 10,11,-1, -1, 0 !#21LM
EDGE 9,11, -1, -1, 0 !#22IM
EDGE 8,11, -1, -1, 0 !#23HM
EDGE 7,11, -1, -1, 0 !#24GM
EDGE 6,11, -1, -1, 0 !#25FM
EDGE 1,12, -1, -1, 0 !#26AN
EDGE 5,12, -1, -1, 0 !#27EN
EDGE 4,12, -1, -1, 0 !#28DN
EDGE 3,12, -1, -1, 0 !#29CN
EDGE 2,12, -1, -1, 0 !#30BN
PGON 3, 0, -1,-25,11,21 !#1MFL
PGON 3, 0, -1,-21,12,22 !#2MLI
PGON 3, 0, -1,23,-22,13 !#3HMI
PGON 3, 0, -1,24,-23,14 !#4GMH
PGON 3, 0, -1,15,25,-24 !#5GFM
PGON 3, 0, -1,1,-11,10 !#6ALF
PGON 3, 0, -1,3,-12,2 !#7EIL
PGON 3, 0, -1,4,5,-13 !#8IDH
PGON 3, 0, -1,6,7,-14 !#9HCG
PGON 3, 0, -1,-15,8,9 !#10FGB
PGON 3, 0, -1,-1,16,-2 !#11LAE
PGON 3, 0, -1,-3,17,-4 !#12IED
PGON 3, 0, -1,-6,-5,18 !#13CHD
PGON 3, 0, -1,19,-8,-7 !#14CBG
PGON 3, 0, -1,-9,20,-10 !#15FBA
PGON 3, 0, -1,-16,26,-27 !#16EAN
PGON 3, 0, -1,-17,27,-28 !#17DEN
PGON 3, 0, -1,28,-29,-18 !#18DNC
PGON 3, 0, -1,-30,-19,29 !#19NBC
PGON 3, 0, -1,30,-26,-20 !#20BNA
end
0 REPLIES 0
Learn and get certified!