3D-Objekt mit verschiedenen Ebenen

[Anonymous]

Gerne würde ich ein 3D-Bibliothekselement eines relativ komplizierteren Elements (Das 3D skript wird sehr lange nach dem Laden des Moprhs als Bib-Element) erstellen und dort Paramter wie zum Besipiel das ein und ausblenden eines Sockels oder das wählen von einem von 2 verschiedenen Logos. Nun ist meine Frage ob es eine Möglichkeit gibt, dass man die verschiedenen 3D- Element wie im 2D auf verschiedene Ebenen (1-16) legt und dann im Parameter-Skript sowie im 3D-Skript die Änderungen eingibt..

z.B. Etwa so:

If logo = "ref nr 0900" then
fragment2 1,0
fragment2 2,0
endif

If logo = "ref nr 0910" then
fragment2 1,0
fragment2 3,0
endif

[Anonymous]

So sollte das aussehen:

IF objtyp="Rahmen einfach"  THEN gosub "Rahmen1"
IF objtyp="Rahmen doppelt"  THEN gosub "Rahmen2"
IF objtyp="Rahmen dreifach"  THEN gosub "Rahmen3"

END

!  -> Ab hier Unterprogramme

"Rahmen1":  ! einfach

RETURN


"Rahmen2":  ! doppelt

RETURN


"Rahmen3":  ! dreifach

RETURN

[bjoern1]

Ja, ich hatte dazwischen noch Variablen, das mochte er scheinbar nicht, danke dir.

weiteres Thema, was sich mir noch nicht erschliesst... Ich möchte gerne die Innenkanten (rot im Bild markiert) weniger rund haben als die äusseren Kanten, das wird doch sicher über die Statuswerte geregelt, oder?
Ich habe diese Statuswerte noch nicht wirklich verinnerlicht...



Vielen Dank

[Anonymous]

Nicht den Statuswert, sondern die Höhe der Phase/Ausrundung = Radius.

[bjoern1]

Hallo Lars,

anbei der Code, die 0.004 sind die Rundung der inneren und äusseren Kanten, kann ich das hier noch genauer bestimmen? Ich habe durch das 5+5ein Loch in das hprism_ geschnitten, aber ich sehe nicht die Möglichkeit (Aufgrund meines Unwissens) den Radius zu ändern vom Ausschnitt.

lg Björn

HPRISM_ mat1,mat2,mat3,mat4,
		5+5,zzyzx,0,0.004,1,		 
		0, 0, 15,
		A, 0, 15,
		A, B, 15,
		0, B, 15,
		0, 0, -1,

	C1, C, 15,
	D1, C, 15,
	D1, D, 15,
	C1, D, 15,
	C1, C, -1 



DEL 2						!!--------------------------> Schalter

ROTy 270
addz -D1
ROTz 270
addx zzyzx-E
addy L

	EXTRUDE 5,0,0,A-C*2, 1+2+4+16+32,
			0, 		L, 		15,
			F, 		G, 		15,
			E,		D2,		15,
			0,		D2,		15,
			0,		L,		-1

[Frank Beister]

Der Radius ist für ein HPRISM auch immer gleich. Dann musst Du das z.B. mit SEO-Befehlen zusammenbauen:

! Definition Grundwerte statt Parameterliste

mat1=SYMB_MAT
mat2=SYMB_MAT
mat3=SYMB_MAT
mat4=SYMB_MAT

A=0.2
B=0.2
ZZYZX=0.06

C=0.045
C1=0.045

D=B-C
D1=A-C1

sts=1+2+8 ! Statuswert Kanten. Ohne 4 verschwinden die Linien on top

RESOL 48  ! Auflösung Krümmung


! Form mit großem Radius ohne Loch

GROUP "Aussen"

R=0.025

HPRISM_ mat1,mat2,mat3,mat4,
      5,zzyzx,0,R,1,      
      0, 0, sts,
      A, 0, sts,
      A, B, sts,
      0, B, sts,
      0, 0, -1
ENDGROUP


! Form mit kleinem Radius und v.a. Loch

GROUP "AussenMitLoch"

R=0.004

HPRISM_ mat1,mat2,mat3,mat4,
      5+5,zzyzx,0,R,1,      
      0, 0, sts,
      A, 0, sts,
      A, B, sts,
      0, B, sts,
      0, 0, -1,

   C1, C, sts,
   D1, C, sts,
   D1, D, sts,
   C1, D, sts,
   C1, C, -1

ENDGROUP

! Geometrisches, logisches UND beider Formen: 

Schalterrahmen = ISECTGROUP ("Aussen", "AussenMitLoch")

! Und Ausgabe:

!PLACEGROUP "Aussen"  ! nur zum Nachvollziehen

!PLACEGROUP "AussenMitLoch"  ! nur zum Nachvollziehen

PLACEGROUP Schalterrahmen

Aber Du bist sicher, dass Du Architektur machst. 😉 Bei dem Detailierungsgrad brauchst Du eine Wahnsinns-Performance für die Darstellung.

[Frank Beister]

[ Das mit den SEOs ist sehr speziell, weil es so aussieht als definiere man Variablen oder Parameter mit dem

Schalterrahmen =

Ist es auch im Prinzip. Aber halt Variablen vom Typ "3D-Körper". Das kommt ausschließlich im Zusammenhang mit den SEO-Befehlen vor. So was ähnliches gibt es noch bei PARAGRAPH und TEXTBLOCK.

Das hatte ich bei der Schulung nicht werwähnt, weil es zu Anfang verwirrt. Ist für Dein Problem aber die eleganteste Lösung. Verbeiß Dich nicht in zu komplexen Problemen. 😉 ]

[bjoern1]

Hallo Frank,

das ist perfekt, ich habe nun einiges schon hinbekommen, aber bin noch nicht zufrieden gewesen. Nein Architektur mache ich derzeit noch nicht damit...,-) Aber kleine Varianten einiger Schaltersysteme mit einem UI_pict stehen schon mal, aber nun wird es konkreter. Soll ja auch was bringen...,-).

Was ich noch nicht ganz verstanden habe ist die Skalierung von Bildern im UI, da wird mir alles als ein Ausschnitt angezeigt, aber das kommt auch noch, nun möchte ich erstmal die Geometrie richtig machen.

Danke dir!