Wallhole Materials

[Lingwisyer]

Hi all,

Does anyone know how the default doors and windows modify the material of the hole they create within a wall?



Ling.

[Barry Kelly]

I believe it is just a case of setting the material before the WALLHOLE commend.

I actually use the WALLNICHE command so I can get a different material on the inside and outside.
I just set it to match the internal and external wall surfaces.
I also set a different pen for the internal and external lines so I can change them if I need to.

Something like this.

m1=1	!!the polygon will create a visible edge upon entry into the body being cut
m2=1	!!depth - the lengthwise edge of the cutting form will be visible
m3=1	!!the polygon will create a visible edge upon exiting the body being cut
m4=0	!!outside - the bottom edge of the cutting form will be visible
m5=0	!!inside - the top edge of the cutting form will be visible
m7=0	!!controls the viewpoint dependent visibility of the lengthwise edge

PEN pen_lin
MATERIAL WALL_MAT_B
WALLNICHE 4, 1, 1*0 + 2*1 + 8*0 + 16*0 + 32*0 + 64*0 + 128*0,
0, 0, 1, -K_-extend_niche,
	-(a*0.5),0,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7,
	(a*0.5),0,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7,
	(a*0.5),b,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7,
	(-a*0.5),b,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7


PEN pen_lin_int
MATERIAL WALL_MAT_A
WALLNICHE 4, 1, 1*0 + 2*1 + 8*0 + 16*0 + 32*0 + 64*0 + 128*0,
0, 0, 1, C_-K_+extend_niche,
	-(a*0.5),0,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7,
	(a*0.5),0,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7,
	(a*0.5),b,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7,
	(-a*0.5),b,1*m1 + 2*m2 + 4*m3 + 8*m4 + 16*m5 + 64*m7

Barry.

[Lingwisyer · Accepted solution]

Coolios. That was easy enough. Two niches, one for the interior, one for the exterior. Creates a hole with four options for the material; inside, outside, side, wrap.

If gs_wall_mat = "Interior" then
		SET MATERIAL WALL_MAT_A
	else
		If gs_wall_mat = "Side" then
				SET MATERIAL WALL_MAT_EDGE
			else
				SET MATERIAL WALL_MAT_B
		endIf
endIf

WallNiche 4, 1, 2,
	0,	0,	1,	-WIDO_SILL,
	0,	0,	0,
	A,	0,	0,
	A,	B,	0,
	0,	B,	0

If gs_wall_mat = "Wrap" then
		SET MATERIAL WALL_MAT_A
endIf

WallNiche 4, 1, 2,
	0,	0,	1,	WALL_THICKNESS,
	0,	0,	0,
	A,	0,	0,
	A,	B,	0,
	0,	B,	0

Ling.