Random texture origin for FOR – TO – NEXT

[jc4d]

Hello,

I have a simple block using FOR – TO – NEXT to duplicate it, is there a way to add a random texture origin to each duplicated so there is no visible texture repetitions?

Juan.

[Lingwisyer]

Is it rotated? It is a bit hard to see in your image as your texture size is significantly bigger than your board size...

VERT	0 + tile_fill_origin_x[iDis],	0 + tile_fill_origin_y[iDis],	0	!Origin
VERT	1 + tile_fill_origin_x[iDis],	0 + tile_fill_origin_y[iDis],	0	!X 
VERT	0 + tile_fill_origin_x[iDis],	1 + tile_fill_origin_y[iDis],	0	!Y 
VERT	0 + tile_fill_origin_x[iDis],	0 + tile_fill_origin_y[iDis],	1	!Z 
coor	2+1024,	-1,	-2,	-3,	-4 

Ling.

[jc4d]

Yes, in my case the texture doesn't "follow" the board size. But the texture is not rotated.

Could it be that I'm approaching this whole thing in the wrong way? 🤔

This is my surface:

3D script:

N1= CEIL(A /(RimaA+RimaV))

FOR H=1 TO N1
GOSUB 20
ADDx RimaV + RimaA
NEXT H


DEL TOP
END

20:
block RimaA, RimaB, B
RETURN

Juan

[Barry Kelly · Accepted solution]

Try this ...

Just use your surface material.

I have only offset in the 'y' direction.

And maybe turn the 'random origin' off in your surface material (mine is off).

board_width = 0.100
board_gap = 0.010

N1= CEIL(A /(board_width+board_gap))

FOR H=1 TO N1
GOSUB 20
ADDx board_width + board_gap
NEXT H


DEL TOP
END

20:

MATERIAL "Timber_Pine - vertical"
block board_width, B, ZZYZX
texture_origin_y = RND(10)
GOSUB 100

RETURN


100: !!texture mapping

VERT 0,0+texture_origin_y,0 !Origin
VERT 1,0+texture_origin_y,0 !X direction
VERT 0,1+texture_origin_y,0 !Y direction
VERT 0,0+texture_origin_y,1 !Z direction
COOR 2+256,1,2,3,4
body -1

RETURN

Barry.

[Barry Kelly]

Mind you, if you texture is big enough you may not even need the VERT/COOR gosub.

You can see here the repetition without VERT/COOR - not great but it is OK.

If you are using the VERT/COOR gosub, you are really just using the first edge of the material.

I guess you could add in a 'texture_origin_x' offset as well which I took out of my example.

Your texture only needs to be one board width if you do use it, but a bigger texture is fine because you can use it for other situations as well as in sheeting rather than boards.

Barry.

[jc4d]

Thank you, now I started understanding the logic (somehow 😅) . Some things are more difficult than expected,

Juan

[jc4d]

In my case I'm using a texture that is meant for wood panels more than borads, so having an offset in x and in z it helped a lot to avoid any tiling in any direction.

The reason for all this is that those boards are going to be used as inner ceilings in open spaces that can cover up to 15m by 15m, and if you count that each board is 5cm wide, you can image how does it looks if there is no texture offset.

Juan

[Lingwisyer]

Hi Peter,

Can the seed range be used to randomise a material?

MATERIAL mat_array[int(rnd(SYMB_POS_X % mat_count)) + 1]

I was hoping to use it within a loop to randomly use between 1 and 5 random materials, but the RND does not change within the loop, only when the object is placed again...

Ling.

[Peter Baksa]

COOR{3} expects that the texture axis coordinates are expressed in the space before moving the origin (unlike XFORM).

It is much simpler to let GDL do the transformations, and use the current coordinate system with COOR{3}:

add dx, dy, dz
rotz da
coor{3} 2, 4,
	0,0,0,
	1,0,0,
	0,1,0,
	0,0,1
del 2
body -1

Don't forget body -1 when modeling objects in a loop.

[Peter Baksa]

Sorry, my mistake, I oversimpified the example. What worked for me is:

int(rnd(_seed * _rangemax) % _rangemax) + 1

Here seed should be a fractional number greater than one to always utilize the whole range.

[Lingwisyer]

Hi Peter,

MATERIAL mat_array[int(rnd(abs(SYMB_POS_X) * mat_count) % mat_count) + 1]

Is giving me a static number per instance of the object.

Ling.